# handles puppetmasterd service
class puppet::master::passenger {
  # Make sure we're not running mongrel
  # Useful when migrating from mongrel to passenger
  $disable_mongrel = hiera('puppet::master::passenger::disable_mongrel', false)
  if $disable_mongrel == true {
    include puppet::master::mongrel::disabled
  }

  # We need a custom envvars apache config to set correct LANG env, see
  # https://projects.puppetlabs.com/issues/11303
  # https://projects.puppetlabs.com/issues/11860
  class { 'apache::envvars':
    source => "puppet:///modules/puppet/envvars.${::lsbdistcodename}",
  }

  # then include puppet class
  include puppet::daemon

  package { 'puppetmaster-passenger':
    ensure => installed,
  }

  $listen   = hiera('puppet::daemon::port', '8140')
  $certname = hiera('puppet::master::certname', "puppet.${::domain}")

  # manage puppetmaster vhost
  file { '/etc/apache2/sites-available/puppetmaster':
    ensure  => present,
    owner   => root,
    group   => root,
    mode    => 0644,
    content => template("puppet/passenger.erb"),
    notify  => Service['apache'],
  }
}