# handles puppetmasterd service
class puppet::master::passenger {
  # Make sure we're not running mongrel
  # Useful when migrating from mongrel to passenger
  $disable_mongrel = hiera('puppet::master::passenger::disable_mongrel', false)
  if $disable_mongrel == true {
    include puppet::master::mongrel::disabled
  }

  # then include puppet class
  include puppet::daemon

  package { 'puppetmaster-passenger':
    ensure => installed,
  }

  $listen   = hiera('puppet::daemon::port', '8140')
  $certname = hiera('puppet::master::certname', "puppet.${::domain}")

  # Legacy configuration
  file { [ '/etc/apache2/sites-available/puppetmaster', '/etc/apache2/sites-enabled/puppetmaster' ]:
    ensure => absent,
    notify => Service['apache'],
  }

  # manage puppetmaster vhost
  file { '/etc/apache2/sites-available/puppetmaster.conf':
    ensure  => present,
    owner   => root,
    group   => root,
    mode    => 0644,
    content => template("puppet/passenger.erb"),
    notify  => Service['apache'],
  }

  file { "/etc/apache2/sites-enabled/puppetmaster.conf":
    owner  => root,
    group  => root,
    ensure => "/etc/apache2/sites-available/puppetmaster.conf",
    notify => Service["apache"],
  }
}