class database {
  include mysql::server

  # See http://www.smilecouple.org/2011/03/01/fix-out-of-resource-problem-with-mysql
  file { '/etc/security/limits.d/mysql.conf':
    ensure  => absent,
    owner   => root,
    group   => root,
    mode    => 0644,
    content => "mysql soft nofile 24000\nmysql hard nofile 32000\n",
  }

  # Avoid Errcode: 24
  file { '/etc/mysql/conf.d/mysqld_open_files_limit.cnf':
    ensure  => present,
    owner   => root,
    group   => root,
    mode    => 0644,
    content => "[mysqld]\nopen-files-limit = 5000\n",
    notify  => Service['mysql'],
  }

  # Database definitions
  define instance($password, $ensure = 'present', $privileges = 'all') {
    mysql_database { "$name":
      ensure  => $ensure,
      require => Service['mysql'],
    }

    mysql_user { "$name@%":
      ensure        => $ensure,
      password_hash => mysql_password($password),
      require       => Mysql_database["$name"],
    }

    if $ensure == 'present' {
      mysql_grant { "$name@%/$name":
        privileges => $privileges,
        require    => Mysql_user["$name@%"],
      }
    }
  }
}