class nodo::role::master {
  $main        = hiera('nodo::role::master::main',        false)
  $db_password = hiera('nodo::role::master::db_password', '')

  case $db_password {
    '': { fail("Please set nodo::master::db_password in your config") }
  }

  if $main == true {
    # Puppetmaster should be included before nodo::virtual
    class { 'puppet::master':
      main => true,
    }

    # The main master has a host entry pointing to itself, other
    # masters still retrieve catalogs from the main master.
    #
    # For that we're relying just on DNS entries.
    host { "puppet":
      ensure       => absent,
      ip           => "127.0.0.1",
      host_aliases => ["puppet.${::domain}"],
    }
  } else {
    class { 'puppet::master':
      main => false,
    }

    host { "puppet":
      ensure => absent,
    }
  }

  # These should be included after puppetmaster
  include nodo::role::virtual
  include database
  include git::daemon
  include nodo::subsystem::monitor::master
  include websites

  # Update master's puppet.conf if you change here
  database::instance { "puppet":
    password => "${db_password}",
  }

  # Used for trac dependency graphs
  package { "graphviz":
    ensure => present,
  }

  # Check domain registration
  domain_check::instance { $::domain: }
}