class nodo {
  include lsb
  include puppetd
  include backup
  include sudo
  include users::admin
  include motd
  include utils
  include cron
  include hosts
  include locales
  include tunnel

  # Set timezone and ntp config
  #
  # We config those here but leave class inclusion elsewhere
  # as ntp config differ from server to vserver.
  #
  $ntp_timezone = "Brazil/East"
  $ntp_pool     = "south-america.pool.ntp.org"
  $ntp_servers  = [ 'a.ntp.br', 'b.ntp.br', 'c.ntp.br' ]

  # Monkeysphere
  #
  # Currently we don't have a defined policy regarding whether
  # to publish all our node keys to public keyservers, so leave
  # automatic publishing disabled for now.
  #
  $monkeysphere_publish_key = false
  include monkeysphere

  # Email delivery configuration
  case $mail_delivery {
    'tunnel': {              
      tunnel::mail { "$mail_hostname":
        sshport   => "$mail_ssh_port",
      }
    }
    'postfix': { }
    '','exim',default: { include exim }
  }

  # Apt configuration
  if $use_apt != false {
    $backports_enabled = true
    $apt_update_method = 'cron'
    include apt
  }

  # Default SSH configuration
  $sshd_password_authentication = "yes"
  $sshd_shared_ip               = "yes"
  $sshd_tcp_forwarding          = "yes"

  file { "/etc/hostname":
    owner   => "root",
    group   => "root",
    mode    => 0644,
    ensure  => present,
    content => "$fqdn\n",
  }

  file { "/etc/rc.local":
    source  => "puppet://$server/modules/nodo/etc/rc.local",
    owner   => "root",
    group   => "root",
    mode    => 0755,
    ensure  => present,
  }

  file { "/etc/screenrc":
    source  => "puppet://$server/modules/nodo/etc/screenrc",
    owner   => "root",
    group   => "root",
    mode    => 0644,
    ensure  => present,
  }

  file { "/etc/profile":
    source  => "puppet://$server/modules/nodo/etc/profile",
    owner   => "root",
    group   => "root",
    mode    => 0644,
    ensure  => present,
    require => File['/usr/local/bin/prompt.sh'],
  }

  file { "/etc/bash.bashrc":
    source  => "puppet://$server/modules/nodo/etc/bash.bashrc",
    owner   => "root",
    group   => "root",
    mode    => 0644,
    ensure  => present,
    require => File['/usr/local/bin/prompt.sh'],
  }

  file { "/usr/local/bin/prompt.sh":
    source  => "puppet://$server/modules/nodo/bin/prompt.sh",
    owner   => "root",
    group   => "root",
    mode    => 0755,
    ensure  => present,
  }
}