class nodo::master {
  $main_master = hiera('nodo::master::main', false)

  if $main_master == true {
    # Puppetmaster should be included before nodo::vserver
    class { 'puppetmasterd':
      main => true,
    }

    include munin::host
    include munin::plugins::muninhost

    # The main master has a host entry pointing to itself, other
    # masters still retrieve catalogs from the main master.
    host { "puppet":
      ensure => present,
      ip     => "127.0.0.1",
      alias  => ["puppet.$domain"],
    }
  } else {
    class { 'puppetmasterd':
      main => false,
    }

    host { "puppet":
      ensure => absent,
    }
  }

  # These should be included after puppetmaster
  include nodo::vserver
  include database
  include git-manager
  include websites::admin
  include nagios::headless
  include nagios::defaults

  # Nagios apache workaround
  file { "/etc/apache2/conf.d/nagios3.conf":
    ensure => absent,
  }

  case $puppetmaster_db_password {
    '': { fail("Please set \$puppetmaster_db_password in your host config") }
  }

  # Update master's puppet.conf if you change here
  database::instance { "puppet":
    password => "$puppetmaster_db_password",
  }

  # Used for trac dependency graphs
  package { "graphviz":
    ensure => present,
  }

  # Check domain registration
  domain::check { $domain: }
}