# Fully capable node able to host other nodes
class nodo::host inherits nodo {
  include initramfs
  include modprobe
  include firewire
  include sysctl
  include utils::physical
  include resolver
  include monkeysphere_nodo

  class { 'syslog-ng': }

  # Firewall configuration
  include firewall

  # Vserver configuration
  $vserver_vdirbase = "/var/vservers"
  include vserver::host

  # Monitoring
  if !defined('monitor') {
    class { 'monitor':
      type       => 'host',
      use_nagios => hiera('host_use_nagios', true),
    }
  }

  # Time configuration
  case $ntpdate {
    false:   { include timezone }
    default: { include ntpdate  }
  }

  # SSH Server
  #
  # We need to restrict listen address so multiple instances
  # can live together in the same physical host.
  #
  case $sshd_listen_address {
    '': { $sshd_listen_address = [ "$ipaddress", '127.0.0.1' ] }
  }

  class { 'sshd':
    listen_address          => $sshd_listen_address,
    password_authentication => $sshd_password_authentication,
    shared_ip               => $sshd_shared_ip,
    tcp_forwarding          => $sshd_tcp_forwarding,
    hardened_ssl            => $sshd_hardened_ssl,
    print_motd              => $sshd_print_motd,
  }

  backupninja::sys { "sys":
    ensure => present,
  }

  # Munin configuration
  munin_node { "$hostname":
    port => '4900',
  }

}