class nodo::base::laptop inherits nodo::base::personal {
  include nodo::utils::laptop
  include nodo::subsystem::dhclient
  include firewall::wifi
  include firewall::openvpn
  include firewall::ppp

  class { 'nodo::subsystem::fstab':
    type => 'laptop',
  }

  $hibernate = hiera('nodo::laptop::hibernate', false)

  class { 'nodo::subsystem::crypttab':
    type => $hibernate ? {
      false   => "laptop",
      default => "laptop.hibernate",
    },
  }

  # Hibernation
  file { "/etc/initramfs-tools/conf.d/resume":
    owner     => "root",
    group     => "root",
    mode      => 0644,
    content   => "RESUME=/dev/mapper/cswap\n",
    notify    => Exec['update-initramfs'],
    ensure    => $hibernate ? {
      false   => absent,
      default => present,
    },
  }

  file { "/etc/uswsusp.conf":
    owner     => "root",
    group     => "root",
    mode      => 0644,
    source    => 'puppet:///modules/nodo/etc/uswsusp.conf',
    require   => Package['uswsusp'],
    ensure    => $hibernate ? {
      false   => absent,
      default => present,
    },
  }

  # Avoid this annoying warning
  # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=673818
  file { '/etc/laptop-mode/conf.d/board-specific':
    ensure  => directory,
    owner   => root,
    group   => root,
    mode    => 0755,
    require => Package['laptop-mode-tools'],
  }

  file { '/etc/laptop-mode/conf.d/board-specific/bogus.conf' :
    ensure  => present,
    owner   => 'root',
    group   => 'root',
    mode    => '0644',
    content => "# Placeholder file, see Debian bug #673818\n",
    require => File['/etc/laptop-mode/conf.d/board-specific'],
  }
}