# Fully capable node able to host other nodes
class nodo::base::host {
  include nodo::subsystem::initramfs
  include nodo::subsystem::modprobe
  include nodo::subsystem::firewire
  include nodo::subsystem::sysctl
  include nodo::subsystem::resolver
  include nodo::utils::physical
  include nodo::utils::storage::crypto
  class { 'syslog-ng': }

  monkeysphere_host { "${::hostname}": }

  # Firewall
  class { 'firewall': }

  # Vserver
  if $::lsbdistcodename == 'squeeze' {
    $vserver = hiera('nodo::host::use_vserver', True)

    if $vserver == true {
      class { 'virtual::vserver::host':
        vdirbase => "/var/vservers",
      }
    }
  }

  # Time
  $ntpdate = hiera('nodo::host::ntpdate', True)
  case $ntpdate {
    false:   { class { 'ntp::timezone': } }
    default: { class { 'ntp::ntpdate':  } }
  }

  # Backup
  backupninja::sys { "sys":
    ensure => present,
    doluks => $::is_virtual,
    dolvm  => $::is_virtual,
    #dombr  => $::is_virtual,
    #dobios => $::is_virtual,
  }

  # Monitoring
  if !defined(Class['nodo::subsystem::monitor']) {
    class { 'nodo::subsystem::monitor': }
  }

  # Munin configuration
  $munin = hiera('nodo::host::use_munin', True)
  if $munin == true {
    munin_node { "$hostname":
      port => '4900',
    }
  }
}