class mail::firma(
  $subdomain = hiera('firma_subdomain', 'firma')
) {

  # Firma subsystems
  include mail::firma::packages

  postfix::config { "firma_destination_recipient_limit": value => '1', nonstandard => true }

  postfix::transport_regexp_snippet { 'firma_transport_regexp':
    content => template('mail/firma/transport_regexp.erb'),
  }

  postfix::virtual_regexp_snippet { 'firma_virtual_regexp':
    content => template('mail/firma/virtual_regexp.erb'),
  }

  postfix::transport { "${subdomain}.$domain":
    ensure      => absent,
    destination => "firma",
  }

  group { "firma":
    ensure    => present,
    allowdupe => false,
  }

  user { "firma":
    ensure    => present,
    allowdupe => false,
    gid       => 'firma',
    require   => Group['firma'],
    home      => '/var/lib/firma',
  }

  vcsrepo { "/var/lib/firma":
    ensure   => present,
    provider => git,
    source   => 'git://git.sarava.org/firma.git',
    revision => 'dd0e0c07c15e36743a043955fe5021ade92bc3d1',
    owner    => 'firma',
    group    => 'firma',
    require  => [ User['firma'], Group['firma'] ],
  }

  file { '/usr/local/bin/firma':
    ensure  => '/var/lib/firma/firma',
    owner   => root,
    group   => root,
    require => Vcsrepo['/var/lib/firma'],
  }

  file { '/var/lib/firma/firma.conf':
    ensure => present,
    owner   => firma,
    group   => firma,
    mode    => 0600,
    require => Vcsrepo['/var/lib/firma'],
    source => "puppet:///modules/mail/firma/firma.conf",
  }
}