# Firewall definitions for physical servers
class firewall(
  $device          = hiera('firewall::device',         'eth0'),
  $zone            = hiera('firewall::zone',           '-'),
  $local_net       = hiera('firewall::local_net',      false),
  $in_bandwidth    = hiera('firewall::in_bandwidth',   '100mbps'),
  $out_bandwidth   = hiera('firewall::out_bandwidth',  '100mbps'),
  $device_options  = hiera('firewall::device_options', 'tcpflags,blacklist,routefilter,nosmurfs,logmartians'),
  $vm_address      = hiera('firewall::vm_address',     '192.168.0.0/24'),
  $vm_device       = hiera('firewall::vm_device',      false)
) {
  class { 'shorewall': }

  $rfc1918 = $local_net ? {
    true    => true,
    false   => false,
    default => false,
  }

  #
  # Interfaces
  #
  shorewall::interface { "${device}":
   zone    => $zone,
   rfc1918 => $rfc1918,
   options => $device_options,
  }

  if $vm_device != false {
    shorewall::interface { "${vm_device}":
      zone    => $zone,
      rfc1918 => $rfc1918,
      options => $device_options,
    }
  }

  #
  # Policy
  #
  shorewall::policy { 'vm-net':
    sourcezone      => 'vm',
    destinationzone => 'net',
    policy          => 'ACCEPT',
    order           => 1,
  }

  shorewall::policy { 'fw-net':
    sourcezone      => '$FW',
    destinationzone => 'net',
    policy          => 'ACCEPT',
    order           => 2,
  }

  shorewall::policy { 'fw-vm':
    sourcezone      => '$FW',
    destinationzone => 'vm',
    policy          => 'ACCEPT',
    order           => 3,
  }

  if $vm_device != false {
    shorewall::policy { 'vm-fw':
      sourcezone      => 'vm',
      destinationzone => '$FW',
      policy          => 'ACCEPT',
      order           => 4,
    }
  }


  shorewall::policy { 'net-all':
    sourcezone      => 'net',
    destinationzone => 'all',
    policy          => 'DROP',
    order           => 5,
  }

  shorewall::policy { 'all-all':
    sourcezone      => 'all',
    destinationzone => 'all',
    policy          => 'REJECT',
    order           => 90,
  }

  #
  # Hosts
  #
  $real_subnet_device = $vm_device ? {
    false   => $device,
    default => $vm_device,
  }

  shorewall::host { "${real_subnet_device}-subnet":
    name    => "${real_subnet_device}:${vm_address}",
    zone    => 'vm',
    options => '',
    order   => '1',
  }

  if $zone == '-' {
    shorewall::host { "${device}":
      name    => "${device}:0.0.0.0/0",
      zone    => 'net',
      options => '',
      order   => '2',
    }
  }

  $real_masq_interface = $vm_device ? {
    false   => "${device}:!${vm_address}",
    default => "${device}",
  }

  shorewall::masq { "${device}":
    interface => "${real_masq_interface}",
    source    => "${vm_address}",
    order     => '1',
  }

  #
  # Rules
  #
  shorewall::rule { 'ssh':
    action          => 'SSH/ACCEPT',
    source          => 'net',
    destination     => '$FW',
    proto           => '-',
    destinationport => '-',
    ratelimit       => '-',
    order           => 100,
  }

  shorewall::rule { 'ping':
    action          => 'Ping/ACCEPT',
    source          => 'net',
    destination     => '$FW',
    proto           => '-',
    destinationport => '-',
    ratelimit       => '-',
    order           => 101,
  }

  shorewall::rule { 'http':
    action          => 'HTTP/ACCEPT',
    source          => 'net',
    destination     => '$FW',
    proto           => '-',
    destinationport => '-',
    ratelimit       => '-',
    order           => 102,
  }

  # SSL computational DoS mitigation
  # See http://vincent.bernat.im/en/blog/2011-ssl-dos-mitigation.html
  shorewall::rule { 'https':
    action          => 'HTTPS/ACCEPT',
    source          => 'net',
    destination     => '$FW',
    proto           => '-',
    destinationport => '-',
    ratelimit       => hiera("firewall::ssl_ratelimit", '-'),
    order           => 103,
  }

  $munin_port = $node_munin_port ? {
    ''      => "4900",
    default => "$node_munin_port",
  }

  shorewall::rule { "munin":
    action          => 'ACCEPT',
    source          => 'net',
    destination     => '$FW',
    proto           => 'tcp',
    destinationport => "$munin_port",
    ratelimit       => '-',
    order           => 104,
  }

  #
  # Zones
  #
  shorewall::zone { 'vm':
    type  => 'ipv4',
    order => '2',
  }

  shorewall::zone { 'net':
    type  => 'ipv4',
    order => '3',
  }

  shorewall::zone { 'loc':
    type  => 'ipv4',
    order => 4,
  }

  #
  # Traffic shapping
  #
  shorewall::tcdevices { "${device}":
    in_bandwidth  => "$in_bandwidth",
    out_bandwidth => "$out_bandwidth",
  }

  shorewall::tcrules { "ssh-tcp":
    order       => "1",
    source      => "0.0.0.0/0",
    destination => "0.0.0.0/0",
    protocol    => "tcp",
    ports       => "22",
  }

  shorewall::tcrules { "ssh-udp":
    order       => "1",
    source      => "0.0.0.0/0",
    destination => "0.0.0.0/0",
    protocol    => "udp",
    ports       => "22",
  }

  shorewall::tcclasses { "ssh":
    order     => "1",
    interface => "${device}",
    rate      => "4*full/100",
    ceil      => "full",
    priority  => "1",
  }

  shorewall::tcclasses { "default":
    order     => "2",
    interface => "${device}",
    rate      => "6*full/100",
    ceil      => "full",
    priority  => "2",
    options   => "default",
  }

  if $local_net == true {
    class { "firewall::local": }
  }
}